Syntax des Ergebnisabschnitts
Im Abschnitt outcome einer YARA-L-Abfrage werden Ergebnisvariablen definiert, die die Ausgabe für eine Such- und Dashboard-Abfrage sowie zusätzlichen Kontext und Informationen zu einer Erkennung angeben, wenn eine Regel ausgelöst wird. Diese Variablen können für verschiedene Zwecke verwendet werden, z. B. zum Anzeigen relevanter Daten auf Dashboards und zum Erstellen von Risikobewertungen.
Abschnitt „Ergebnis“ definieren
Verwenden Sie das Zeichen $ gefolgt von einem Variablennamen, um eine Ergebnisvariable im Abschnitt outcome einer einzelnen Abfrage zu definieren. Sie können bis zu 20 Ergebnisvariablen definieren. Die Variablennamen selbst sind beliebig. Bei Regeln werden die Ergebniswerte für jede Erkennung berechnet und aggregiert.
Jeder Ergebnisvariablen wird mithilfe eines Ausdrucks ein Wert zugewiesen.
Mit dieser Regel wird nach fehlgeschlagenen Anmeldungen von einem neuen Standort aus gesucht:
rule failed_logins
{
meta:
author = "Security Team"
description = "Detects multiple failed user logins within 10-minute windows."
severity = "HIGH"
events:
$e.metadata.event_type = "USER_LOGIN"
$e.security_result.action = "FAIL"
$user = $e.target.user.userid
match:
$user over 10m
outcome:
$failed_login_count = count($e.metadata.id)
$first_fail_time = min($e.metadata.event_timestamp.seconds)
condition:
#e >= 5
}
Im Abschnitt outcome werden Aggregationen für die Ereignis- und Platzhaltervariablen durchgeführt: Die fehlgeschlagenen Anmeldungen und die unterschiedlichen IP-Adressen werden gezählt und die Zeit des Fehlers wird ermittelt.
outcome:
$failed_login_count = count($e.metadata.id)
$first_fail_time = min($e.metadata.event_timestamp.seconds)
Wenn Sie die spezielle Ergebnisvariable $risk_score einbeziehen und füllen, wird ihr Wert (Ganzzahl oder Gleitkommazahl) auf der Seite Meldungen und IoCs für Meldungen angezeigt, die von der Abfrage generiert wurden.
Wenn Sie im Abschnitt outcome einer Abfrage keine $risk_score-Variable angeben, wird einer der folgenden Standardwerte festgelegt:
Wenn die Abfrage so konfiguriert ist, dass eine Benachrichtigung generiert wird, wird
$risk_scoreauf 40 gesetzt.Wenn die Abfrage nicht so konfiguriert ist, dass eine Benachrichtigung generiert wird, wird
$risk_scoreauf 15 gesetzt.
Der Wert von $risk_score wird im UDM-Feld security_result.risk_score gespeichert.
Ergebnisvariable „risk_score“
Google SecOps Risk Analytics verknüpft Erkennungen und Warnungen automatisch mit Entitäten, die mit dieser Erkennung oder Warnung in Verbindung stehen. Die Ergebnisvariable risk_score wird verwendet, um ein Risikoniveau zuzuweisen. Wenn dieser Wert nicht festgelegt ist, wird der Standardwert für die Erkennung oder Benachrichtigung verwendet. Sie können Standardwerte in den Einstellungen konfigurieren.
Um die Konsistenz auf der gesamten Plattform zu gewährleisten, empfehlen wir, die folgenden Punktzahlbereiche zu verwenden, wenn Sie Ihren benutzerdefinierten Erkennungen einen risk_score zuweisen. Diese Abstimmung hilft, die Priorisierung von Benachrichtigungen und die Reaktionsworkflows zu standardisieren.
| Schweregrad | Bewertungsbereich | Beschreibung | Beispiel |
|---|---|---|---|
| Benachrichtigung – Kritisch | 90–100 | Aktive Kompromittierung mit potenziellen Auswirkungen über ein einzelnes Nutzerkonto oder einen einzelnen Endpunkt hinaus. Sofortige Überprüfung erforderlich. | Mimikatz wurde auf dem Domaincontroller ausgeführt. |
| Benachrichtigungen – Hoch | 80–89 | Aktive Kompromittierung eines einzelnen Endpunkts oder einer einzelnen Entität. Sollte sofort überprüft werden. | Produktionsserver, der einen kürzlich bekannten C2 aufruft. |
| Benachrichtigungen – Mittel | 50–79 | Potenzielles Sicherheitsproblem, das untersucht werden muss. Keine bestätigte Manipulation, aber Eskalation ist möglich. | Anmeldedaten wurden offengelegt, es gibt aber keine Anzeichen für Missbrauch. |
| Keine Benachrichtigung – Niedrig | 20–49 | Sicherheitsereignis mit geringen Auswirkungen, das in Kombination mit anderen Indikatoren oder Beobachtungen zu einem schwerwiegenderen Vorfall führen könnte. In der Regel ist keine Überprüfung erforderlich. Kann mit anderen Erkennungen über zusammengesetzte Regeln kombiniert werden, um eine Benachrichtigung zu erstellen. | Interner Portscan. |
| Beobachtungen ohne Benachrichtigung | 1–19 | Im Allgemeinen sind dies informationsbasierte Erkennungen, die dazu dienen, ein Lagebild einer Bedrohung zu erstellen. Erfordert in der Regel keine Überprüfung. Kann mit anderen Erkennungen über zusammengesetzte Regeln kombiniert werden, um Benachrichtigungen zu generieren. | Ein Anmeldeereignis, keine Anzeichen von Missbrauch. |
Da risk_score eine Ergebnisvariable ist, können Ihre Regeln je nach Faktoren wie Threat Intelligence oder anderen gleichzeitigen Bedingungen Nuancen ausdrücken.
Risikobewertungen für Entitäten können verwendet werden, um risikobasierte Benachrichtigungen nahezu in Echtzeit zu generieren. Weitere Informationen finden Sie unter Risk Analytics – Übersicht.
Ergebnisvariable „risk_entity_to_score“
Standardmäßig weist Google SecOps allen Entitäten in den Stichprobenereignissen die Risikobewertung einer Erkennung zu. Außerdem wird die Bewertung allen Entitäten zugewiesen, die in den Abschnitten match und outcome der Regel erfasst werden. Wenn Sie die Risikobewertung stattdessen bestimmten Entitäten zuweisen möchten, geben Sie zusätzlich zu risk_score die Ergebnisvariable risk_entity_to_score an. Die Risikobewertung unterstützt user- und asset-Entitäten. Die Entitätstypen RESOURCE und GROUP werden nicht unterstützt.
Sie können mehrere risk_entity_to_score-Variablen erstellen, indem Sie der Variablen einen eindeutigen String anhängen und die Risikobewertung bestimmten Entitäten zuweisen. Beispiel:
$risk_entity_to_score_source_asset = $e.principal.asset.hostname
$risk_entity_to_score_targeted_user = $e.target.user.userid
Diese Ergebnisvariablen weisen den im Abschnitt outcome der Regel angegebenen risk_score den Entitäten $e.principal.asset.hostname und $e.target.user.userid zu.
Beispiel: Regel erkennt Anmeldungen in Administratorkonten
Mit dieser Regel werden erfolgreiche Anmeldungen bei Administratorkonten mit hohen Berechtigungen erkannt. Dabei wird das Schlüsselwort risk_entity_to_score verwendet, um explizit den angemeldeten Nutzer anzusprechen. Mit dieser Variable wird sichergestellt, dass der berechnete Risikowert nur für diesen Nutzer und nicht für andere am Ereignis beteiligte Entitäten wie die Quell-IP-Adresse gilt.
Weitere Informationen zum Schreiben einer Regel für mehrere Ereignisse finden Sie unter Regel für mehrere Ereignisse.
rule suspicious_admin_privilege_escalation {
// This rule matches single events. Rules can also match multiple events within
// the same time window.
meta:
// Allows for storage of arbitrary key-value pairs of rule details, such as
// who wrote it, what it detects on, and version control.
// The "author" and "severity" fields are special, since they are used as
// columns on the rules dashboard. To sort based on these fields on the
// dashboard, add them here.
// Severity value should be "Low", "Medium", or "High"
author = "analyst123"
description = "Detects suspicious login to critical admin accounts."
severity = "HIGH"
events:
$e.metadata.event_type = "USER_LOGIN"
$e.target.user.attribute.roles.name = "ADMIN"
$e.security_result.summary = "Successful login with high-privilege access"
outcome:
// Multi-event rules require an aggregation function
// For example, risk_score = max(0)
// See https://docs.cloud.google.com/chronicle/docs/yara-l/yara-l-2-0-examples#outcome_conditionals_example_rule
$risk_score = 80
$risk_entity_to_score = $e.target.user.userid
$source_ip = array_distinct($e.principal.ip)
condition:
$e
}
Beispiel: Regel überwacht interne Netzwerkverbindungen
Diese Regel prüft auf Lateral Movement, indem Netzwerkverbindungen zwischen internen Netzwerksegmenten identifiziert werden. Dabei wird $risk_entity_to_score prefix verwendet, um mehreren Entitäten innerhalb einer einzelnen Erkennung ein Risiko zuzuweisen. Sowohl für den initiierenden Host ($risk_entity_to_score_source_asset) als auch für den Zielnutzer ($risk_entity_to_score_targeted_user) werden die Risikobewertungen aktualisiert. Die Risiko-Engine zeichnet andere Ergebnisvariablen auf, die dieses spezifische Präfix nicht für den Kontext verwenden, ignoriert sie jedoch (ihre Risikobewertungen bleiben gleich).
Weitere Informationen zum Schreiben einer Regel für mehrere Ereignisse finden Sie unter Regel für mehrere Ereignisse und Beispielregel für Ergebnisbedingungen.
rule lateral_movement_network_connection {
// This rule matches single events. You can also match multiple events within
// the same time window.
meta:
// Allows for storage of arbitrary key-value pairs of rule details (for
// example, who wrote it, what it detects on, and version control).
// The "author" and "severity" fields are special, since they are used as
// columns on the rules dashboard. To sort based on these fields on the
// dashboard, add them here. Severity value should be "Low", "Medium" or "High"
author = "analyst123"
description = "Detects lateral movement attempts between internal segments."
severity = "MEDIUM"
events:
$e.metadata.event_type = "NETWORK_CONNECTION"
$e.principal.asset.hostname != ""
$e.target.user.userid != ""
// Can also use: $e.target.ip = /10\..*/
net.ip_in_range_cidr($e.target.ip, "10.0.0.0/8")
outcome:
// Multi-event rules require an aggregation function
// for example, risk_score = max(0)
// See https://docs.cloud.google.com/chronicle/docs/yara-l/yara-l-2-0-examples#outcome-conditionals-example-rule
$risk_score = 50
$risk_entity_to_score_source_asset = $e.principal.asset.hostname
$risk_entity_to_score_targeted_user = $e.target.user.userid
$target_ip_info = array_distinct($e.target.ip)
condition:
$e
}
Datentypen für Ergebnisvariablen
Jede Ergebnisvariable kann einen anderen Datentyp haben, der durch den Ausdruck bestimmt wird, mit dem sie berechnet wird. Die folgenden Ergebnisdatentypen werden in Google SecOps unterstützt:
- integer
- floats
- String
- Listen mit Ganzzahlen
- Listen mit Gleitkommazahlen
- Listen mit Strings
Bedingte Logik
Sie können bedingte Logik verwenden, um den Wert eines Ergebnisses zu berechnen. Bedingungen werden mit dem folgenden Syntaxmuster angegeben:
if(BOOL_CLAUSE, THEN_CLAUSE)
if(BOOL_CLAUSE, THEN_CLAUSE, ELSE_CLAUSE)
Ein bedingter Ausdruck kann so gelesen werden: „Wenn BOOL_CLAUSE wahr ist, wird THEN_CLAUSE zurückgegeben, andernfalls ELSE_CLAUSE“.
BOOL_CLAUSE muss als boolescher Wert ausgewertet werden. Ein BOOL_CLAUSE-Ausdruck hat eine ähnliche Form wie Ausdrücke im Abschnitt events. Er kann beispielsweise Folgendes enthalten:
UDM-Feldnamen mit Vergleichsoperator:
if($context.graph.entity.user.title = "Vendor", 100, 0)Platzhaltervariable, die im Abschnitt
eventsdefiniert wurde:if($severity = "HIGH", 100, 0)Eine weitere Ergebnisvariable, die im Abschnitt
outcomedefiniert ist:if($risk_score > 20, "HIGH", "LOW")Funktionen, die einen booleschen Wert zurückgeben:
if(re.regex($e.network.email.from, `.*altostrat.com`), 100, 0)In einer Referenzliste nachsehen:
if($u.principal.hostname in %my_reference_list_name, 100, 0)Vergleich der Aggregation:
if(count($login.metadata.event_timestamp.seconds) > 5, 100, 0)
THEN_CLAUSE und ELSE_CLAUSE müssen denselben Datentyp haben. Wir unterstützen Ganzzahlen, Gleitkommazahlen und Strings.
Sie können die ELSE_CLAUSE weglassen, wenn der Datentyp eine Ganzzahl oder eine Gleitkommazahl ist. Wenn ELSE_CLAUSE weggelassen wird, wird sie als 0 ausgewertet. Beispiel:
`if($e.field = "a", 5)` is equivalent to `if($e.field = "a", 5, 0)`
Sie müssen die ELSE_CLAUSE angeben, wenn der Datentyp ein String ist oder wenn die THEN_CLAUSE eine Platzhaltervariable oder Ergebnisvariable ist.
Mathematische Operationen
Sie können mathematische Operationen verwenden, um Ganzzahl- oder Gleitkomma-Datentypen in den Abschnitten outcome und events einer Abfrage zu berechnen. Google Security Operations unterstützt Addition, Subtraktion, Multiplikation, Division und Modulo als Operatoren auf oberster Ebene in einer Berechnung.
Das folgende Snippet ist eine Beispielberechnung im Abschnitt outcome:
outcome:
$risk_score = max(100 + if($severity = "HIGH", 10, 5) - if($severity = "LOW", 20, 0))
Mathematische Operationen sind für die folgenden Operandentypen zulässig, sofern jeder Operand und der gesamte arithmetische Ausdruck ordnungsgemäß aggregiert sind (siehe Aggregationen):
- Felder für numerische Ereignisse
- Numerische Platzhaltervariablen, die im Abschnitt
eventsdefiniert sind - Numerische Ergebnisvariablen, die im Abschnitt
outcomedefiniert sind - Funktionen, die Ganzzahlen oder Gleitkommazahlen zurückgeben
- Aggregationen, die Ganzzahlen oder Gleitkommazahlen zurückgeben
Modulus ist für Gleitkommazahlen nicht zulässig.
Standardmäßige Ganzzahlliterale sind standardmäßig vorzeichenbehaftete 64-Bit-Ganzzahlen (INT64), die nicht mit vorzeichenlosen 64-Bit-Ganzzahl-UDM-Feldern (UINT64) wie network.received_bytes, network.sent_bytes und principal.file.size kompatibel sind.
Die Kombination dieser Typen in arithmetischen (+, -, *) oder Modulo-Operationen (%) kann im Abschnitt outcome zu einem Laufzeitfehler führen. Verwenden Sie cast.as_int() oder cast.as_uint(), um Ganzzahltypen abzugleichen und dieses Problem zu beheben. Für den Operator % ist eine explizite Umwandlung erforderlich. Bei arithmetischen Operationen können Sie Ganzzahlkonstanten auch dazu zwingen, sich wie Gleitkommazahlen zu verhalten. Verwenden Sie dazu Gleitkommaliterale wie 2.0 oder 100.0 oder eine Division wie (2/1) in Ausdrücken ohne andere /-Operatoren in derselben Zeile. Weitere Informationen finden Sie unter Arithmetik mit vorzeichenlosen Ereignisfeldern.
Platzhaltervariablen in Ergebnissen
Beim Berechnen von Ergebnisvariablen können Sie Platzhaltervariablen verwenden, die im Ereignisabschnitt Ihrer Abfrage definiert wurden. In diesem Beispiel wird davon ausgegangen, dass $email_sent_bytes im Abschnitt „Ereignisse“ der Regel definiert wurde:
Beispiel: Einzelereignis ohne Übereinstimmungsabschnitt
// No match section, so this is a single-event query. outcome: // Use placeholder directly as an outcome value. $my_outcome = $email_sent_bytes // Use placeholder in a conditional. $other_outcome = if($file_size > 1024, "SEVERE", "MODERATE") condition: $e
Beispiel: Mehrere Ereignisse mit Abschnitt „match“
match:
// This is a multi event query with a match section.
$hostname over 5m
outcome:
// Use placeholder directly in an aggregation function.
$max_email_size = max($email_sent_bytes)
// Use placeholder in a mathematical computation.
$total_bytes_exfiltrated = sum(
1024.0
+ $email_sent_bytes
+ $file_event.principal.file.size
)
condition:
$email_event and $file_eventErgebnisvariablen in Ausdrücken für die Ergebniszuweisung
Ergebnisvariablen können verwendet werden, um andere Ergebnisvariablen abzuleiten, ähnlich wie Platzhaltervariablen, die im Abschnitt events definiert sind. Sie können bei der Zuweisung einer anderen Ergebnisvariablen auf eine Ergebnisvariable verweisen. Verwenden Sie dazu ein $-Token, gefolgt vom Variablennamen. Ergebnisvariablen müssen definiert werden, bevor im Abfragetext auf sie verwiesen werden kann. Wenn Ergebnisvariablen in einem Zuweisungsausdruck verwendet werden, dürfen sie nicht aggregiert werden (siehe Aggregations).
Im folgenden Beispiel wird der Wert der Ergebnisvariable $risk_score von der Ergebnisvariable $event_count abgeleitet:
Beispiel: Ergebnisvariable, die von einer anderen Ergebnisvariable abgeleitet wurde
match: // This is a multi event query with a match section. $hostname over 5m outcome: // Aggregates all timestamp on login events in the 5 minute match window. $event_count = count($login.metadata.event_timestamp.seconds) // $event_count cannot be aggregated again. $risk_score = if($event_count > 5, "SEVERE", "MODERATE") // This is the equivalent of the 2 outcomes combined. $risk_score2 = if(count($login.metadata.event_timestamp.seconds) > 5, "SEVERE", "MODERATE") condition: $e
Ergebnisvariablen können in jedem Ausdruckstyp auf der rechten Seite einer Ergebniszuweisung verwendet werden, mit Ausnahme der folgenden Ausdrücke:
- Zusammenfassungen
Arrays.length()-Funktionsaufrufe- Mit den Modifikatoren
anyoderall
Zusammenfassungen
Wiederkehrende Ereignisfelder sind nicht skalare Werte. Das bedeutet, dass eine einzelne Variable auf mehrere Werte verweist. Die Ereignisfeldvariable $e.target.ip ist beispielsweise ein wiederkehrendes Feld und kann null, einen oder viele IP-Werte enthalten. Es ist ein nicht skalarer Wert. Die Ereignisfeldvariable $e.principal.hostname ist dagegen kein wiederkehrendes Feld und hat nur einen Wert (d.h. einen Skalarwert).
Ebenso sind sowohl nicht wiederholte Ereignisfelder als auch wiederholte Ereignisfelder, die im Abschnitt outcome einer Abfrage mit einem Übereinstimmungsfenster verwendet werden, nicht skalare Werte.
Beispiel: Gruppenereignisse mit Übereinstimmungsabschnitt und nicht wiederkehrendem Feld
In der folgenden Abfrage werden Ereignisse mithilfe eines „match“-Abschnitts gruppiert und im „outcome“-Abschnitt wird auf ein nicht wiederholtes Ereignisfeld verwiesen:
rule OutcomeAndMatchWindow{
...
match:
$userid over 5m
outcome:
$hostnames = array($e.principal.hostname)
...
}Jedes 5-Minuten-Fenster, in dem die Abfrage ausgeführt wird, kann null, ein oder viele Ereignisse enthalten. Der Ergebnisabschnitt gilt für alle Ereignisse in einem Übereinstimmungsfenster. Jede Ereignisfeldvariable, auf die im Ergebnisabschnitt verwiesen wird, kann auf null, einen oder mehrere Werte des Felds für jedes Ereignis im Abgleichsfenster verweisen.
Wenn ein 5-Minuten-Fenster beispielsweise 5 $e-Ereignisse enthält, verweist $e.principal.hostname im Abschnitt „Ergebnis“ auf fünf verschiedene Hostnamen. Die Ereignisfeldvariable $e.principal.hostname wird im Abschnitt outcome dieser Abfrage als nicht skalarer Wert behandelt.
Da Ergebnisvariablen immer einen einzelnen skalaren Wert liefern müssen, muss jeder nicht skalare Wert, von dem eine Ergebniszuweisung abhängt, aggregiert werden, um einen einzelnen skalaren Wert zu erhalten. In einem Ergebnisabschnitt sind die folgenden Werte nicht skalar und müssen aggregiert werden:
- Ereignisfelder (wiederholt oder nicht wiederholt), wenn die Abfrage einen
match-Abschnitt verwendet - Ereignisplatzhalter (wiederholt oder nicht wiederholt), wenn die Abfrage einen
match-Abschnitt verwendet - Wiederkehrende Ereignisfelder, wenn in der Abfrage kein
match-Abschnitt verwendet wird - Platzhalter für wiederkehrende Termine, wenn in der Abfrage kein
match-Abschnitt verwendet wird
Skalare Ereignisfelder, skalare Ereignisplatzhalter und Konstanten können in Abfragen, die keinen match-Abschnitt enthalten, in Aggregationsfunktionen eingeschlossen werden. In den meisten Fällen geben diese Aggregationen jedoch den verpackten Wert zurück, sodass sie nicht erforderlich sind.
Eine Ausnahme ist die Aggregation array(), mit der Sie einen skalaren Wert explizit in ein Array konvertieren können.
Ergebnisvariablen werden wie Aggregationen behandelt: Sie dürfen nicht noch einmal aggregiert werden, wenn sie in einer anderen Ergebniszuweisung referenziert werden.
Sie können die folgenden Aggregationsfunktionen verwenden:
| Aggregatfunktion | Beschreibung |
|---|---|
max() |
Gibt den Höchstwert aller möglichen Werte aus. Funktioniert nur mit Ganzzahlen und Gleitkommazahlen. |
min() |
Gibt den Mindestwert aller möglichen Werte aus. Funktioniert nur mit Ganzzahlen und Gleitkommazahlen. |
sum() |
Gibt die Summe aller möglichen Werte aus. Funktioniert nur mit Ganzzahlen und Gleitkommazahlen. |
count_distinct() |
Erfasst alle möglichen Werte und gibt dann die Anzahl der eindeutigen möglichen Werte aus. |
count() |
Verhält sich wie „count_distinct()“, gibt aber eine nicht eindeutige Anzahl möglicher Werte zurück. |
array_distinct() |
Erfasst alle möglichen eindeutigen Werte und gibt dann eine Liste dieser Werte aus. Zuerst wird die Deduplizierung angewendet, um eine Liste mit eindeutigen Werten zu erstellen, und dann die Kürzung. In der Suche wird die Liste auf maximal 1.000 zufällige Elemente gekürzt. In Dashboards und Regeln wird die Liste auf maximal 25 zufällige Elemente gekürzt. |
array() |
Verhält sich wie array_distinct(), gibt aber eine Liste von Werten zurück, die nicht eindeutig sind. In der Suche wird die Liste auf maximal 1.000 zufällige Elemente gekürzt. In Dashboards und Regeln wird die Liste auf maximal 25 zufällige Elemente gekürzt. |
Die Aggregatfunktion ist wichtig, wenn eine Regel einen condition-Abschnitt enthält, der angibt, dass mehrere Ereignisse vorhanden sein müssen, da die Aggregatfunktion auf alle Ereignisse angewendet wird, die die Erkennung generiert haben.
Beispiel: Bedingung für mehrere Ereignisse
Im Folgenden finden Sie ein Beispiel für eine Bedingung für mehrere Ereignisse. Wenn der Abschnitt mit den Ergebnissen und Bedingungen Folgendes enthält:
outcome: $asset_id_count = count($event.principal.asset_id) $asset_id_distinct_count = count_distinct($event.principal.asset_id) $asset_id_list = array($event.principal.asset_id) $asset_id_distinct_list = array_distinct($event.principal.asset_id) condition: #event > 1
Da im Abschnitt „condition“ für jede Erkennung mehr als ein „event“ erforderlich ist, werden die Aggregatfunktionen für mehrere Ereignisse ausgeführt. Angenommen, die folgenden Ereignisse haben eine Erkennung generiert:
event: // UDM event 1 asset_id="asset-a" event: // UDM event 2 asset_id="asset-b" event: // UDM event 3 asset_id="asset-b"
Dann sind die Werte Ihrer Ergebnisse:
- $asset_id_count = 3
- $asset_id_distinct_count = 2
- $asset_id_list = `["asset-a", "asset-b", "asset-b"]
- $asset_id_distinct_list = `["asset-a", "asset-b"]
Beschränkungen
Im Abschnitt
outcomekann nicht auf eine neue Platzhaltervariable verwiesen werden, die nicht bereits im Abschnitteventsoder im Abschnittoutcomedefiniert wurde.Im Abschnitt
outcomekönnen keine Ereignisvariablen verwendet werden, die nicht im Abschnitteventsdefiniert wurden.Im Abschnitt
outcomekann ein Ereignisfeld verwendet werden, das im Abschnitteventsnicht verwendet wurde, sofern die Ereignisvariable, zu der das Ereignisfeld gehört, bereits im Abschnitteventsdefiniert wurde.Im Abschnitt
outcomekönnen nur Ereignisvariablen korreliert werden, die bereits im Abschnitteventskorreliert wurden. Korrelationen treten auf, wenn zwei Ereignisfelder aus verschiedenen Ereignisvariablen gleichgesetzt werden.
Beispiele für den Abschnitt outcome finden Sie unter Übersicht über YARA-L 2.0.
Weitere Informationen zur Deduplizierung von Erkennungen mit dem Abschnitt outcome finden Sie unter Kontextsensitive Analysen erstellen.
Nächste Schritte
Weitere Informationen
- In YARA-L 2.0 verwendete Ausdrücke, Operatoren und Konstrukte
- Funktionen in YARA-L 2.0
- Zusammengesetzte Erkennungsregeln erstellen
- Beispiele: YARA-L 2.0-Abfragen
Benötigen Sie weitere Hilfe? Antworten von Community-Mitgliedern und Google SecOps-Experten erhalten