Wiederkehrende Felder
Im Unified Data Model (UDM) sind einige Felder als wiederholt gekennzeichnet. Das bedeutet, dass es sich um Listen mit Werten oder anderen Nachrichtentypen handelt. In diesem Dokument finden Sie Informationen zur Verwendung von Ausdrücken, Platzhaltern, Array-Indexierung und wiederholten Nachrichten für wiederholte UDM-Felder.
Boolesche Ausdrücke und wiederkehrende Felder
Geänderte und unveränderte boolesche Ausdrücke können auf wiederkehrende Felder angewendet werden.
Betrachten Sie das folgende Ereignis:
event_original {
principal {
// ip is a repeated field
ip: [ "192.0.2.1", "192.0.2.2", "192.0.2.3" ]
hostname: "host"
}
}
Geänderte Ausdrücke
Verwenden Sie die Modifikatoren any und all in Ausdrücken in wiederkehrenden Feldern.
any: Wenn ein beliebiges Element des wiederkehrenden Felds die Bedingung erfüllt, erfüllt das Ereignis insgesamt die Bedingung. Beispiel:event_originalerfülltany $e.principal.ip = "192.0.2.1"event_originalschlägt fehlany $e.repeated_field.field_a = "9.9.9.9"
all: Wenn alle Elemente des wiederkehrenden Felds die Bedingung erfüllen, erfüllt das Ereignis insgesamt die Bedingung. Beispiel:event_originalerfülltnet.ip_in_range_cidr(all $e.principal.ip, "192.0.2.0/8")event_originalschlägt fehlall $e.principal.ip = "192.0.2.2"
Wenn Sie eine Bedingung mit any oder all schreiben, beachten Sie, dass die Negation der Bedingung mit not möglicherweise nicht dieselbe Bedeutung hat wie die Verwendung des negierten Operators.
Beispiel:
not all $e.principal.ip = "192.168.12.16"prüft, ob nicht alle IP-Adressen mit192.168.12.16übereinstimmen. Das bedeutet, dass die Abfrage prüft, ob mindestens eine IP-Adresse nicht mit192.168.12.16übereinstimmt.all $e.principal.ip != "192.168.12.16"prüft, ob alle IP-Adressen nicht mit192.168.12.16übereinstimmen. Das bedeutet, dass die Abfrage prüft, ob keine IP-Adressen mit192.168.12.16übereinstimmen.
Einschränkungen:
- Die Operatoren
anyundallsind nur mit wiederkehrenden Feldern (nicht mit skalaren Feldern) kompatibel. anyundallkönnen nicht verwendet werden, um zwei wiederkehrende Felder zu verknüpfen.any $e1.principal.ip = $e2.principal.ipist beispielsweise ungültig.- Die Operatoren
anyundallwerden beim Ausdruck für die Referenzliste nicht unterstützt.
Unveränderte Ausdrücke
Betrachten Sie beispielsweise ein Ereignis, bei dem das Feld security_result ein wiederkehrendes Feld ist:
security_result[0].threat_id = "threat_a"
security_result[1].threat_id = "threat_b"
security_result[1].rule_name = "rule_b"
security_result[2].threat_id = "threat_c"
Eine unveränderte Suchanfrage wie $e.security_result.rule_name = "" gibt dieses Ereignis zurück, da das Standardverhalten für wiederkehrende Felder als true ausgewertet wird, wenn ein Element die Bedingung erfüllt. Die Abfrage stimmt mit dem Index 0 und dem Index 2 überein, wobei das Feld rule_name nicht vorhanden ist (ein leerer String).
Ebenso entspricht dasselbe Ereignis der Abfrage $e.security_result.rule_name != "", da die Bedingung bei Index 1 erfüllt ist.
Mit dem Operator all können Sie prüfen, ob das Feld rule_name in allen security_result-Elementen fehlt: all $e.security_result.rule_name = "". Diese Abfrage stimmt nicht mit dem Beispielereignis überein.
Bei unveränderten Ausdrücken wird jedes Element im wiederkehrenden Feld einzeln behandelt. Wenn das wiederkehrende Feld eines Ereignisses n Elemente enthält, wird die Abfrage auf n Kopien des Ereignisses angewendet, wobei jede Kopie eines der Elemente des wiederkehrenden Felds enthält. Diese Kopien sind temporär und werden nicht gespeichert.
Für das vorherige Beispiel-Dataset event_original wird eine Regel auf die folgenden Kopien angewendet:
| event copy | principal.ip | principal.hostname |
|---|---|---|
| event_copy_1 | "192.0.2.1" | "host" |
| event_copy_2 | "192.0.2.2" | "host" |
| event_copy_3 | "192.0.2.3" | "host" |
Wenn eine Ereigniskopie alle unveränderten Bedingungen im wiederkehrenden Feld erfüllt, erfüllt das Ereignis insgesamt alle Bedingungen. Wenn Sie also mehrere Bedingungen für ein wiederkehrendes Feld haben, muss eine einzelne Ereigniskopie alle Bedingungen erfüllen. In den folgenden Abfragebeispielen wird das vorherige Beispiel-Dataset verwendet, um dieses Verhalten zu demonstrieren.
Beispiel: Unveränderte Ausdrücke
Die folgende Regel gibt eine Übereinstimmung zurück, wenn sie für das Beispiel-Dataset event_original ausgeführt wird, da event_copy_1 alle Ereignis-Prädikate erfüllt:
rule repeated_field_1 {
meta:
events:
net.ip_in_range_cidr($e.principal.ip, "192.0.2.0/8") // Checks if IP address matches 192.x.x.x
$e.principal.ip = "192.0.2.1"
condition:
$e
}
Die folgende Regel gibt keine Übereinstimmung zurück, wenn sie für das Beispieldataset event_original ausgeführt wird, da es in $e.principal.ip keine Ereigniskopie gibt, die _alle_ Ereignis-Prädikate erfüllt.
rule repeated_field_2 {
meta:
events:
$e.principal.ip = "192.0.2.1"
$e.principal.ip = "192.0.2.2"
condition:
$e
}
Geänderte Ausdrücke in wiederkehrenden Feldern sind mit unveränderten Ausdrücken in wiederkehrenden Feldern kompatibel, da die Elementliste für jede Ereigniskopie gleich ist. Beachten Sie die folgende Regel:
rule repeated_field_3 {
meta:
events:
any $e.principal.ip = "192.0.2.1"
$e.principal.ip = "192.0.2.3"
condition:
$e
}
Die Regel wird auf die folgenden Kopien angewendet:
| event copy | principal.ip | any $e.principal.ip |
|---|---|---|
| event_copy_1 | "192.0.2.1" | ["192.0.2.1", "192.0.2.2", "192.0.2.3"] |
| event_copy_2 | "192.0.2.2" | ["192.0.2.1", "192.0.2.2", "192.0.2.3"] |
| event_copy_3 | "192.0.2.3" | ["192.0.2.1", "192.0.2.2", "192.0.2.3"] |
In diesem Fall erfüllen alle Kopien any $e.principal.ip = "192.0.2.1", aber nur event_copy_3 erfüllt $e.principal.ip = "192.0.2.3". Daher würde das Ereignis insgesamt übereinstimmen.
Eine andere Möglichkeit, diese Ausdruckstypen zu betrachten, ist:
- Ausdrücke für wiederkehrende Felder, die
anyoderallverwenden, werden auf die Liste inevent_originalangewendet. - Ausdrücke für wiederkehrende Felder, die nicht
anyoderallverwenden, werden auf einzelneevent_copy_n-Ereignisse angewendet.
Platzhalter und wiederkehrende Felder
Wiederkehrende Felder funktionieren mit Platzhalterzuweisungen. Ähnlich wie bei unveränderten Ausdrücken in wiederkehrenden Feldern wird für jedes Element eine Kopie des Ereignisses erstellt. Wenn wir das Beispiel event_copy verwenden, nimmt der Platzhalter den Wert des wiederkehrenden Felds von event_copy_n für jede der Ereigniskopien an, wobei n die Nummer der Ereigniskopie ist. Wenn der Platzhalter im Abgleichbereich verwendet wird, kann dies zu mehreren Übereinstimmungen führen.
Beispiel: Platzhalter für wiederkehrendes Feld
Im folgenden Beispiel wird eine Übereinstimmung generiert. Der Platzhalter „$ip“ entspricht „192.0.2.1“ für „event_copy_1“, was die Prädikate in der Regel erfüllt. Die Ereignisbeispiele der Übereinstimmung enthalten ein einzelnes Element, `event_original`.
// Generates 1 match.
rule repeated_field_placeholder1 {
meta:
events:
$ip = $e.principal.ip
$ip = "192.0.2.1"
$host = $e.principal.hostname
match:
$host over 5m
condition:
$e
}
Im folgenden Beispiel werden drei Übereinstimmungen generiert. Der Platzhalter $ip entspricht für jede der verschiedenen event_copy_n-Kopien unterschiedlichen Werten.
Die Gruppierung erfolgt nach $ip, da sich dieses Feld im Abschnitt „match“ befindet. Sie erhalten also drei Übereinstimmungen, wobei jede Übereinstimmung einen anderen Wert für die Übereinstimmungsvariable $ip hat. Jede Übereinstimmung hat dasselbe Ereignisbeispiel: ein einzelnes Element, event_original.
// Generates 3 matches.
rule repeated_field_placeholder2 {
meta:
events:
$ip = $e.principal.ip
net.ip_in_range_cidr($ip, "192.0.2.0/8") // Checks if IP matches 192.x.x.x
match:
$ip over 5m
condition:
$e
}
Ergebnisse bei Verwendung von Platzhaltern, die wiederkehrenden Feldern zugewiesen sind
Platzhalter werden jedem Element jedes wiederkehrenden Felds zugewiesen, nicht der gesamten Liste. Wenn sie im Abschnitt outcome verwendet werden, wird das Ergebnis nur anhand der Elemente berechnet, die die vorherigen Abschnitte erfüllt haben.
Beachten Sie die folgende Regel:
rule outcome_repeated_field_placeholder {
meta:
events:
$ip = $e.principal.ip
$ip = "192.0.2.1" or $ip = "192.0.2.2"
$host = $e.principal.hostname
match:
$host over 5m
outcome:
$o = array_distinct($ip)
condition:
$e
}
Diese Regel wird in vier Phasen ausgeführt. Die erste Phase ist das Kopieren von Ereignissen:
| event copy | $ip | $host | $e |
|---|---|---|---|
| event_copy_1 | "192.0.2.1" | "host" | event_id |
| event_copy_2 | "192.0.2.2" | "host" | event_id |
| event_copy_3 | "192.0.2.3" | "host" | event_id |
Im Abschnitt „Ereignisse“ werden dann Zeilen herausgefiltert, die nicht mit den Filtern übereinstimmen:
| event copy | $ip | $host | $e |
|---|---|---|---|
| event_copy_1 | "192.0.2.1" | "host" | event_id |
| event_copy_2 | "192.0.2.2" | "host" | event_id |
event_copy_3 wird herausgefiltert, weil "192.0.2.3" nicht $ip = "192.0.2.1" or $ip = "192.0.2.2" erfüllt.
Der Abschnitt match wird dann nach Übereinstimmungsvariablen gruppiert und im Abschnitt outcome wird eine Aggregation für jede Gruppe durchgeführt:
| $host | $o | $e |
|---|---|---|
| "host" | ["192.0.2.1", "192.0.2.2"] | event_id |
$o = array_distinct($ip) wird anhand von $ip aus der vorherigen Phase berechnet, nicht aus der Phase des Kopierens von Ereignissen.
Im Abschnitt condition werden die einzelnen Gruppen gefiltert. Da diese Regel nur das Vorhandensein von $e prüft, wird für die Zeile von vorhin eine einzelne Erkennung erzeugt.
$o enthält nicht alle Elemente aus $e.principal.ip, da nicht alle Elemente alle Bedingungen im Abschnitt „Ereignisse“ erfüllt haben. Alle Elemente von e.principal.ip werden jedoch im Ereignisbeispiel angezeigt, da im Ereignisbeispiel event_original verwendet wird.
Array-Indexierung
Sie können die Array-Indexierung für wiederkehrende Felder ausführen. Verwenden Sie die Standardlistensyntax, um auf das n-te wiederkehrende Feldelement zuzugreifen (Elemente sind 0-indexiert). Für ein Element außerhalb des Bereichs wird der Standardwert zurückgegeben.
$e.principal.ip[0] = "192.168.12.16"$e.principal.ip[999] = ""Wenn weniger als 1.000 Elemente vorhanden sind, wird dies alstrueausgewertet.
Einschränkungen:
- Ein Index muss ein nicht negatives Ganzzahlliteral sein.
$e.principal.ip[-1]ist beispielsweise ungültig. - Werte mit dem Typ
int(z. B. ein Platzhalter, der aufintgesetzt ist) werden nicht berücksichtigt. - Die Array-Indexierung kann nicht mit
anyoderallkombiniert werden.any $e.intermediary.ip[0]ist beispielsweise ungültig. - Die Array-Indexierung kann nicht mit der Kartensyntax kombiniert werden.
$e.additional.fields[0]["key"]ist beispielsweise ungültig. - Wenn der Feldpfad mehrere wiederkehrende Felder enthält, müssen alle wiederkehrenden Felder die Array-Indexierung verwenden. Beispiel:
$e.intermediary.ip[0]ist nicht gültig, daintermediaryundipwiederkehrende Felder sind, aber nur ein Index füripvorhanden ist.
Wiederholte Nachrichten
Wenn ein message-Feld wiederholt wird, kann dies unbeabsichtigt die Wahrscheinlichkeit einer Übereinstimmung verringern. Dies wird in den folgenden Beispielen veranschaulicht.
Betrachten Sie das folgende Ereignis:
event_repeated_message {
// about is a repeated message field.
about {
// ip is a repeated string field.
ip: [ "192.0.2.1", "192.0.2.2", "192.0.2.3" ]
hostname: "alice"
}
about {
hostname: "bob"
}
}
Wie bei unveränderten Ausdrücken in wiederkehrenden Feldern wird für jedes Element des wiederkehrenden Felds eine temporäre Kopie des Ereignisses erstellt. Beachten Sie die folgende Regel:
rule repeated_message_1 {
meta:
events:
$e.about.ip = "192.0.2.1"
$e.about.hostname = "bob"
condition:
$e
}
Die Regel wird auf die folgenden Kopien angewendet:
| event copy | about.ip | about.hostname |
|---|---|---|
| event_copy_1 | "192.0.2.1" | "alice" |
| event_copy_2 | "192.0.2.2" | "alice" |
| event_copy_3 | "192.0.2.3" | "alice" |
| event_copy_4 | "" | "bob" |
Das Ereignis stimmt nicht mit der Regel überein, da es keine Ereigniskopie gibt, die alle Ausdrücke erfüllt.
Wiederholte Nachrichten und Array-Indexierung
Ein weiteres unerwartetes Verhalten kann auftreten, wenn die Array-Indexierung mit unveränderten Ausdrücken für wiederholte Nachrichtenfelder verwendet wird. Sehen Sie sich die folgende Beispielregel an, die die Array-Indexierung verwendet:
rule repeated_message_2 {
meta:
events:
$e.about.ip = "192.0.2.1"
$e.about[1].hostname = "bob"
condition:
$e
}
Die Regel wird auf die folgenden Kopien angewendet:
| event copy | about.ip | about[1].hostname |
|---|---|---|
| event_copy_1 | "192.0.2.1" | "bob" |
| event_copy_2 | "192.0.2.2" | "bob" |
| event_copy_3 | "192.0.2.3" | "bob" |
| event_copy_4 | "" | "bob" |
Da event_copy_1 alle Ausdrücke in repeated_message_2 erfüllt, stimmt das Ereignis mit der Regel überein.
Dies kann zu unerwartetem Verhalten führen, da die Regel repeated_message_1 keine Array-Indexierung hatte und keine Übereinstimmungen erzeugte, während die Regel repeated_message_2 die Array-Indexierung verwendete und eine Übereinstimmung erzeugte.
Benötigen Sie weitere Hilfe? Antworten von Community-Mitgliedern und Google SecOps-Experten erhalten