הגדרת גישה לשירותים פרטיים ו-Private Service Connect

בדף הזה מוסבר איך להגדיר גישה לשירותים פרטיים ו-Private Service Connect.

הגדרת גישה לשירותים פרטיים מאפשרת לכם להקצות טווח של כתובות IP וליצור חיבור לשירות פרטי בשביל רשת ה-VPC בפרויקט Google Cloud . כך המשאבים ברשת ה-VPC יכולים להתחבר למכונות של Cloud SQL.

הגדרת Private Service Connect מאפשרת להתחבר למכונה ראשית של Cloud SQL או לכל אחת מהרפליקות לקריאה שלה, מכמה רשתות VPC ששייכות לקבוצות, לצוותים, לפרויקטים או לארגונים שונים.

יצירת מכונה שתומכת בגישה לשירותים פרטיים וב-Private Service Connect

כשיוצרים מכונה של Cloud SQL שתומכת גם בגישה לשירותים פרטיים וגם ב-Private Service Connect, נהנים מהיתרונות של שני השירותים. מידע נוסף זמין במאמר אפשרויות חיבור למכונות.

באמצעות Private Service Connect, אתם יכולים להתחבר למכונה של Cloud SQL מכמה רשתות VPC ששייכות לקבוצות, לצוותים, לפרויקטים או לארגונים שונים.

אתם יכולים ליצור מכונה של Cloud SQL שתומכת בגישה פרטית לשירותים וב-Private Service Connect באמצעות ה-CLI של gcloud או ה-API.

gcloud

כדי ליצור מכונה שתומכת גם בגישה לשירותים פרטיים וגם ב-Private Service Connect, משתמשים בפקודה gcloud sql instances create:

gcloud sql instances create INSTANCE_NAME \
--project=PROJECT_ID \
--region=REGION_NAME \
--enable-private-service-connect \
--allowed-psc-projects=ALLOWED_PROJECTS \
--availability-type=AVAILABILITY_TYPE \
--no-assign-ip \
--allocated-ip-range-name=RANGE_NAME \
--database-version=DATABASE_VERSION \
--cpu=NUMBER_OF_vCPUs \
--memory=MEMORY_SIZE \
--root-password=ROOT_PASSWORD \
--network=VPC_PSA_NETWORK_PATH \
--psc-auto-connections=network=VPC_PSC_NETWORK_PATH,project=SERVICE_PROJECT

מחליפים את הפרטים הבאים:

  • ‫INSTANCE_NAME: שם המכונה.
  • ‫PROJECT_ID: המזהה או מספר הפרויקט ב- Google Cloud שמכיל את המכונה.
  • ‫REGION_NAME: שם האזור של המכונה.

  • ‫ALLOWED_PROJECTS: רשימה של מזהי פרויקטים או מספרי פרויקטים מותרים, מופרדים בפסיקים. אם פרויקט לא מופיע ברשימה הזו, אי אפשר ליצור בו נקודות קצה (endpoints) של Private Service Connect כדי להתחבר למכונה.

  • ‫AVAILABILITY_TYPE: הפעלת זמינות גבוהה למכונה. בפרמטר הזה, מציינים את אחד מהערכים הבאים:
    • ‫REGIONAL: הפעלת זמינות גבוהה, מומלץ למכונות בסביבת הייצור. המכונה עוברת למצב של מעבר לגיבוי בעת כשל באזור אחר בתוך האזור שבחרתם.
    • ‫ZONAL: לא מספק יכולת יתירות כשל. זה ערך ברירת המחדל.

    מידע נוסף על הגדרה והסרה של זמינות גבוהה למכונות זמין במאמרים הגדרת מכונה קיימת לזמינות גבוהה והשבתת זמינות גבוהה למכונה.

  • ‫RANGE_NAME: בפרמטר האופציונלי הזה, מגדירים שם לטווח שמוקצה לו טווח של כתובות IP. שם הטווח חייב לעמוד בדרישות של RFC 1035 ולהכיל בין 1 ל-63 תווים.
  • ‫DATABASE_VERSION: גרסת מסד הנתונים של המכונה (לדוגמה, SQLSERVER_2019_STANDARD).
  • ‫NUMBER_OF_vCPUs: מספר הליבות של המכונה.
  • ‫MEMORY_SIZE: נפח הזיכרון של המכונה.
  • ‫ROOT_PASSWORD: הסיסמה של המשתמש ב-root Cloud SQL.
  • ‫VPC_PSA_NETWORK_PATH: השם והנתיב של רשת ה-VPC שאליה המכונה מתחברת (לדוגמה, "projects/PROJECT_ID/global/networks/default"). הרשת הזו משמשת לחיבורים של גישה לשירותים פרטיים ולכתובת ה-IP של הגישה לשירותים פרטיים של מכונת Cloud SQL.
  • ‫VPC_PSC_NETWORK_PATH: הנתיב לרשת ה-VPC שממנה צריך ליצור את נקודת הקצה של Private Service Connect. לדוגמה:
    projects/my-host-project/global/networks/default.

  • ‫SERVICE_PROJECT: הפרויקט שבו נוצרה נקודת הקצה של Private Service Connect. אם רשת ה-VPC היא לא VPC משותף, הפרויקט יכול להיות רק הפרויקט המארח של הרשת. אם זה VPC משותף, הוא יכול להיות הפרויקט המארח או פרויקט השירות.

במאמר התחברות למכונה של Cloud SQL מוסבר איך להתחבר למכונה שמופעל בה Private Service Connect.

כדי להשבית את כתובת ה-IP הציבורית, משתמשים בפרמטר --no-assign-ip.

Terraform

כדי ליצור מכונה שמופעלות בה גם גישה לשירותים פרטיים וגם Private Service Connect, משתמשים במשאב Terraform‏ google_sql_database_instance.


resource "google_compute_network" "peering_network" {
  name                    = "private-network"
  auto_create_subnetworks = "false"
}

resource "google_compute_global_address" "private_ip_address" {
  name          = "private-ip-address"
  purpose       = "VPC_PEERING"
  address_type  = "INTERNAL"
  prefix_length = 16
  network       = google_compute_network.peering_network.id
}

resource "google_service_networking_connection" "default" {
  network                 = google_compute_network.peering_network.id
  service                 = "servicenetworking.googleapis.com"
  reserved_peering_ranges = [google_compute_global_address.private_ip_address.name]
}

resource "google_sql_database_instance" "default" {
  name             = "sqlserver-instance"
  region           = "us-central1"
  database_version = "SQLSERVER_2019_STANDARD"
  root_password    = "INSERT-PASSWORD-HERE"

  depends_on = [google_service_networking_connection.default]

  settings {
    tier = "db-custom-2-7680"
    ip_configuration {
      psc_config {
        psc_enabled               = true
        allowed_consumer_projects = [] # Add consumer project IDs here.
      }
      ipv4_enabled    = false
      private_network = google_compute_network.peering_network.id
    }
  }
}

resource "google_compute_network_peering_routes_config" "peering_routes" {
  peering              = google_service_networking_connection.default.peering
  network              = google_compute_network.peering_network.name
  import_custom_routes = true
  export_custom_routes = true
}

resource "google_compute_address" "default" {
  name         = "psc-compute-address-${google_sql_database_instance.default.name}"
  region       = "us-central1"
  address_type = "INTERNAL"
  subnetwork   = "default"      # Replace value with the name of the subnet here.
  address      = "192.168.0.44" # Replace value with the IP address to reserve.
}

data "google_sql_database_instance" "default" {
  name = resource.google_sql_database_instance.default.name
}

resource "google_compute_forwarding_rule" "default" {
  name                  = "psc-forwarding-rule-${google_sql_database_instance.default.name}"
  region                = "us-central1"
  network               = "default"
  ip_address            = google_compute_address.default.self_link
  load_balancing_scheme = ""
  target                = data.google_sql_database_instance.default.psc_service_attachment_link
}

כך מחילים את ההגדרות של Terraform בפרויקט ב- Google Cloud :

הכנת Cloud Shell

  1. מפעילים את Cloud Shell.

  2. מגדירים את פרויקט ברירת המחדל ב- Google Cloud שבו רוצים להחיל את ההגדרות של Terraform.

    תצטרכו להריץ את הפקודה הזו רק פעם אחת לכל פרויקט, ותוכלו לעשות זאת בכל ספרייה.

    export GOOGLE_CLOUD_PROJECT=PROJECT_ID

    אם תגדירו ערכים ספציפיים בקובץ התצורה של Terraform, הם יבטלו את ערכי ברירת המחדל של משתני הסביבה.

הכנת הספרייה

לכל קובץ תצורה של Terraform צריכה להיות ספרייה משלו (שנקראת גם מודול ברמה הבסיסית).

  1. יוצרים ספרייה חדשה ב-Cloud Shell ובה יוצרים קובץ חדש. שם הקובץ חייב לכלול את הסיומת .tf, למשל main.tf. במדריך הזה, הקובץ נקרא main.tf. 
    mkdir DIRECTORY && cd DIRECTORY && touch main.tf

  2. אם אתם עוקבים אחרי המדריך, תוכלו להעתיק את הקוד לדוגמה בכל קטע או שלב.

    מעתיקים את הקוד לדוגמה בקובץ main.tf החדש שיצרתם.

    לחלופין, אפשר גם להעתיק את הקוד מ-GitHub. כדאי לעשות את זה כשקטע הקוד של Terraform הוא חלק מפתרון מקצה לקצה.

  3. בודקים את הפרמטרים לדוגמה ומשנים אותם בהתאם לסביבה שלכם.
  4. שומרים את השינויים.
  5. מפעילים את Terraform. צריך לעשות זאת רק פעם אחת לכל ספרייה. 
    terraform init

    אופציונלי: תוכלו לכלול את האפשרות -upgrade, כדי להשתמש בגרסה העדכנית ביותר של הספק של Google: 

    terraform init -upgrade

החלה של השינויים

  1. בודקים את ההגדרות ומוודאים שהמשאבים שמערכת Terraform תיצור או תעדכן תואמים לציפיות שלכם: 
    terraform plan

    מתקנים את ההגדרות לפי הצורך.

  2. מריצים את הפקודה הבאה ומזינים yes בהודעה שמופיעה, כדי להחיל את הגדרות Terraform: 
    terraform apply

    ממתינים עד שב-Terraform תוצג ההודעה "Apply complete!‎".

  3. פותחים את הפרויקט ב- Google Cloud כדי להציג את התוצאות. במסוף Google Cloud , נכנסים למשאבים בממשק המשתמש כדי לוודא שהם נוצרו או עודכנו ב-Terraform.

REST

לפני שמשתמשים בנתוני הבקשה, צריך להחליף את הנתונים הבאים:

  • ‫PROJECT_ID: המזהה או מספר הפרויקט ב- Google Cloud שמכיל את המכונה.
  • ‫INSTANCE_NAME: שם המכונה.
  • ‫REGION_NAME: שם האזור של המכונה.
  • ‫ROOT_PASSWORD: הסיסמה של המשתמש ב-root Cloud SQL.
  • ‫AVAILABILITY_TYPE: הפעלת זמינות גבוהה למכונה. בפרמטר הזה, מציינים את אחד מהערכים הבאים:
    • ‫REGIONAL: הפעלת זמינות גבוהה, מומלץ למכונות בסביבת הייצור. המכונה עוברת למצב של מעבר לגיבוי בעת כשל באזור אחר בתוך האזור שבחרתם.
    • ‫ZONAL: לא מספק יכולת יתירות כשל. זה ערך ברירת המחדל.

    מידע נוסף על הגדרה והסרה של זמינות גבוהה למכונות זמין במאמרים הגדרת מכונה קיימת לזמינות גבוהה והשבתת זמינות גבוהה למכונה.

  • ‫VPC_PSA_NETWORK_PATH: הנתיב של רשת ה-VPC שאליה המכונה מתחברת (לדוגמה, "projects/PROJECT_ID/global/networks/default"). הרשת הזו משמשת לחיבורים של גישה לשירותים פרטיים ולכתובת ה-IP של הגישה לשירותים פרטיים של מכונת Cloud SQL.
  • ‫RANGE_NAME: בפרמטר האופציונלי הזה, מגדירים שם לטווח שמוקצה לו טווח כתובות IP. שם הטווח חייב לעמוד בדרישות של RFC 1035 ולהכיל בין תו אחד ל-63 תווים.

  • ‫ALLOWED_PROJECTS: רשימה של מזהי פרויקטים או מספרי פרויקטים מותרים, מופרדים בפסיקים. אם פרויקט לא מופיע ברשימה הזו, אי אפשר ליצור בו נקודות קצה (endpoints) של Private Service Connect כדי להתחבר למכונה.

  • ‫VPC_PSC_NETWORK_PATH: הנתיב לרשת ה-VPC שממנה צריך ליצור את נקודת הקצה של Private Service Connect. לדוגמה:
    projects/my-host-project/global/networks/default.

  • ‫SERVICE_PROJECT: הפרויקט שבו נוצרה נקודת הקצה של Private Service Connect. אם רשת ה-VPC היא לא VPC משותף, הפרויקט יכול להיות רק הפרויקט המארח של הרשת. אם זה VPC משותף, הוא יכול להיות הפרויקט המארח או פרויקט השירות.

  • ‫MACHINE_TYPE: ערך מחרוזת ממוספר שמייצג את סוג המכונה. לדוגמה: db-custom-NUMBER_OF_vCPUs-MEMORY_SIZE, כאשר NUMBER_OF_vCPUs ו-MEMORY_SIZE הם מספר הליבות וכמות הזיכרון שרוצים להקצות למכונה.

במאמר התחברות למכונה של Cloud SQL מוסבר איך להתחבר למכונה שמופעל בה Private Service Connect.

מגדירים את הפרמטר ipv4Enabled לערך false כי למכונה יש כתובת IP פנימית.

ה-method של ה-HTTP וכתובת ה-URL: 

POST https://sqladmin.googleapis.com/v1/projects/PROJECT_ID/instances

תוכן בקשת JSON: 

{
  "name": "INSTANCE_NAME",
  "project": PROJECT_ID",
  "region": "REGION_NAME",
  "databaseVersion": "SQLSERVER_2019_STANDARD",
  "rootPassword": "ROOT_PASSWORD",
  "kind": "sql#instance",
  "settings": {
    "availabilityType": "AVAILABILITY_TYPE",
    "ipConfiguration": {
      "ipv4Enabled": false,
      "privateNetwork": VPC_PSA_NETWORK_PATH,
      "allocatedIpRange": "RANGE_NAME",
      "pscConfig": {
        "allowedConsumerProjects": [
          "ALLOWED_PROJECTS"
        ],
        "pscAutoConnections": [
          {
            "consumerProject":"SERVICE_PROJECT",
            "consumerNetwork":"projects/SERVICE_PROJECT/global/networks/VPC_PSC_NETWORK_PATH"
          }
        ],
        "pscEnabled": true
      }
    },
    "kind": "sql#settings",
    "pricingPlan": "PER_USE",
    "replicationType": "SYNCHRONOUS",
    "tier": "MACHINE_TYPE"
  }
}

כדי לשלוח את הבקשה צריך להרחיב אחת מהאפשרויות הבאות:

אתם אמורים לקבל תגובת JSON שדומה לזו:

{
  "kind": "sql#operation",
  "targetLink": "https://sqladmin.googleapis.com/v1/projects/PROJECT_ID/instances/INSTANCE_NAME",
  "status": "RUNNING",
  "user": "user@example.com",
  "insertTime": "2020-01-16T02:32:12.281Z",
  "startTime": "2023-06-14T18:48:35.499Z",
  "operationType": "CREATE",
  "name": "OPERATION_ID",
  "targetId": "INSTANCE_NAME",
  "selfLink": "https://sqladmin.googleapis.com/v1/projects/PROJECT_ID/operations/OPERATION_ID",
  "targetProject": "PROJECT_ID"
}

השבתת Private Service Connect במכונה

אתם יכולים להשבית את Private Service Connect במכונה שמופעלות בה גם גישה לשירותים פרטיים וגם Private Service Connect.

השבתת Private Service Connect במכונה נמשכת כ-8 דקות, ובמהלכן המכונה מושבתת למשך כ-45 שניות. בסיום הפעולה, נתיבי הקישוריות של הגישה לשירותים הפרטיים ושל Private Service Connect לא יהיו קיימים יותר באותו מכונה. אי אפשר להתחבר למכונה באמצעות Private Service Connect.

כדי להשבית את Private Service Connect במכונה, אתם יכולים להשתמש ב-ה-CLI של gcloud או ב-API.

gcloud

כדי להשבית את Private Service Connect במכונה, משתמשים בפקודה gcloud sql instances patch:

gcloud sql instances patch INSTANCE_NAME \
--project=PROJECT_ID \
--no-enable-private-service-connect \
--clear-allowed-psc-projects

מחליפים את הפרטים הבאים:

  • ‫INSTANCE_NAME: השם של המכונה
  • ‫PROJECT_ID: המזהה או מספר הפרויקט של הפרויקט ב- Google Cloud שמכיל את המכונה

Terraform

כדי להשבית את Private Service Connect במכונה, משתמשים במשאב Terraform של google_sql_database_instance.

resource "google_sql_database_instance" "disable_psc_example" {
  name             = "sqlserver-disable-psc-example"
  region           = "us-central1"
  database_version = "SQLSERVER_2019_STANDARD"
  root_password    = "INSERT-PASSWORD-HERE"

  depends_on = [google_service_networking_connection.default]

  settings {
    tier = "db-custom-2-7680"
    ip_configuration {
      psc_config {
        psc_enabled               = false
        allowed_consumer_projects = [] # clear consumer projects
      }
      ipv4_enabled    = false
      private_network = google_compute_network.peering_network.id
    }
  }
  # set `deletion_protection` to true, will ensure that one cannot accidentally delete this instance by
  # use of Terraform whereas `deletion_protection_enabled` flag protects this instance at the GCP level.
  deletion_protection = false
}

REST

לפני שמשתמשים בנתוני הבקשה, צריך להחליף את הנתונים הבאים:

  • ‫PROJECT_ID: המזהה או מספר הפרויקט של הפרויקט ב- Google Cloud שמכיל את המכונה
  • ‫INSTANCE_NAME: השם של המכונה

ה-method של ה-HTTP וכתובת ה-URL: 

PATCH https://sqladmin.googleapis.com/v1/projects/PROJECT_ID/instances/INSTANCE_NAME

תוכן בקשת JSON: 

{
  "kind": "sql#instance",
  "name": "INSTANCE_NAME",
  "project": "PROJECT_ID",
  "settings": {
    "ipConfiguration": {
      "pscConfig": {
        "pscEnabled": "false",
        "allowedConsumerProjects": [{}]
      }
    },
    "kind": "sql#settings"
  }
}

כדי לשלוח את הבקשה צריך להרחיב אחת מהאפשרויות הבאות:

אתם אמורים לקבל תגובת JSON שדומה לזו:

{
  "kind": "sql#operation",
  "targetLink": "https://sqladmin.googleapis.com/v1/projects/PROJECT_ID/instances/INSTANCE_NAME",
  "status": "RUNNING",
  "user": "user@example.com",
  "insertTime": "2020-01-16T02:32:12.281Z",
  "startTime": "2023-06-14T18:48:35.499Z",
  "operationType": "UPDATE",
  "name": "OPERATION_ID",
  "targetId": "INSTANCE_NAME",
  "selfLink": "https://sqladmin.googleapis.com/v1/projects/PROJECT_ID/operations/OPERATION_ID",
  "targetProject": "PROJECT_ID"
}

הפעלת Private Service Connect במכונה

אתם יכולים להפעיל את Private Service Connect במכונה שכבר מופעלת בה גישה לשירותים פרטיים. אתם יכולים להשתמש ב-Private Service Connect כדי להתחבר למכונה של Cloud SQL מכמה רשתות VPC.

כשמפעילים את Private Service Connect במכונה, הפעולה נמשכת 8 דקות, ובמהלכה המכונה מושבתת למשך כ-45 שניות. בסיום הפעולה, גם נתיבי הקישוריות של הגישה לשירותים פרטיים וגם אלה של Private Service Connect נמצאים באותו מכונה.

כדי להפעיל את Private Service Connect במכונה, אתם יכולים להשתמש ב-ה-CLI של gcloud או ב-API.

gcloud

כדי להפעיל את Private Service Connect במכונה, משתמשים בפקודה gcloud sql instances patch:

gcloud sql instances patch INSTANCE_NAME \
--project=PROJECT_ID \
--enable-private-service-connect \
--allowed-psc-projects=ALLOWED_PROJECTS \
--psc-auto-connections=network=VPC_PSC_NETWORK_PATH,project=SERVICE_PROJECT

מחליפים את הפרטים הבאים:

  • ‫INSTANCE_NAME: השם של המכונה
  • ‫PROJECT_ID: המזהה או מספר הפרויקט של הפרויקט ב- Google Cloud שמכיל את המכונה

  • ‫ALLOWED_PROJECTS: רשימה של מזהי פרויקטים או מספרי פרויקטים מותרים, מופרדים בפסיקים. אם פרויקט לא נכלל ברשימה הזו, אי אפשר ליצור בו נקודות קצה (endpoints) של Private Service Connect כדי להתחבר למכונה.

  • ‫VPC_PSC_NETWORK_PATH: הנתיב לרשת ה-VPC שממנה נוצרה נקודת הקצה של Private Service Connect. לדוגמה:
    projects/my-host-project/global/networks/default.

  • ‫SERVICE_PROJECT: הפרויקט שבו נוצרה נקודת הקצה של Private Service Connect. אם רשת ה-VPC היא לא VPC משותף, הפרויקט יכול להיות רק הפרויקט המארח של הרשת. אם זה VPC משותף, הוא יכול להיות הפרויקט המארח או פרויקט השירות.

במאמר התחברות למכונה של Cloud SQL מוסבר איך להתחבר למכונה שמופעל בה Private Service Connect.

Terraform

כדי להפעיל את Private Service Connect במכונה, משתמשים במשאב Terraform של google_sql_database_instance.

resource "google_sql_database_instance" "default" {
  name             = "sqlserver-instance"
  region           = "us-central1"
  database_version = "SQLSERVER_2019_STANDARD"
  root_password    = "INSERT-PASSWORD-HERE"

  depends_on = [google_service_networking_connection.default]

  settings {
    tier = "db-custom-2-7680"
    ip_configuration {
      psc_config {
        psc_enabled               = true
        allowed_consumer_projects = [] # Add consumer project IDs here.
      }
      ipv4_enabled    = false
      private_network = google_compute_network.peering_network.id
    }
  }
}

REST

לפני שמשתמשים בנתוני הבקשה, צריך להחליף את הנתונים הבאים:

  • ‫PROJECT_ID: המזהה או מספר הפרויקט ב- Google Cloud שמכיל את המכונה.
  • ‫INSTANCE_NAME: שם המכונה.
  • ‫ALLOWED_PROJECTS: רשימה של מזהי פרויקטים או מספרי פרויקטים מותרים, מופרדים בפסיקים. הפרויקטים האלה מבטלים פרויקטים שכבר מוגדרים לשימוש ב-Private Service Connect. אם פרויקט לא נכלל ברשימה הזו, אי אפשר ליצור בו נקודות קצה (endpoints) של Private Service Connect כדי להתחבר למכונה.
  • ‫VPC_PSC_NETWORK_PATH: הנתיב לרשת ה-VPC שממנה נוצרה נקודת הקצה של Private Service Connect. לדוגמה:
    projects/my-host-project/global/networks/default.

  • ‫SERVICE_PROJECT: הפרויקט שבו נוצרה נקודת הקצה של Private Service Connect. אם רשת ה-VPC היא לא VPC משותף, הפרויקט יכול להיות רק הפרויקט המארח של הרשת. אם זה VPC משותף, הוא יכול להיות הפרויקט המארח או פרויקט השירות.

ה-method של ה-HTTP וכתובת ה-URL: 

PATCH https://sqladmin.googleapis.com/v1/projects/PROJECT_ID/instances/INSTANCE_NAME

תוכן בקשת JSON: 

{
  "kind": "sql#instance",
  "name": "INSTANCE_NAME",
  "project": "PROJECT_ID",
  "settings": {
    "ipConfiguration": {
      "pscConfig": {
        "pscAutoConnections": [
          {
            "consumerProject":"SERVICE_PROJECT",
            "consumerNetwork":"projects/SERVICE_PROJECT/global/networks/VPC_PSC_NETWORK_PATH"
          }
        ],
        "pscEnabled": "true",
        "allowedConsumerProjects": [ALLOWED_PROJECTS]
      }
    },
    "kind": "sql#settings"
  }
}

כדי לשלוח את הבקשה צריך להרחיב אחת מהאפשרויות הבאות:

אתם אמורים לקבל תגובת JSON שדומה לזו:

{
  "kind": "sql#operation",
  "targetLink": "https://sqladmin.googleapis.com/v1/projects/PROJECT_ID/instances/INSTANCE_NAME",
  "status": "RUNNING",
  "user": "user@example.com",
  "insertTime": "2020-01-16T02:32:12.281Z",
  "startTime": "2023-06-14T18:48:35.499Z",
  "operationType": "UPDATE",
  "name": "OPERATION_ID",
  "targetId": "INSTANCE_NAME",
  "selfLink": "https://sqladmin.googleapis.com/v1/projects/PROJECT_ID/operations/OPERATION_ID",
  "targetProject": "PROJECT_ID"
}

במאמר התחברות למכונה של Cloud SQL מוסבר איך להתחבר למכונה שמופעל בה Private Service Connect.